/*
    Copyright (C) 2007 Christopher E. Miller
    
    This software is provided 'as-is', without any express or implied
    warranty.  In no event will the authors be held liable for any damages
    arising from the use of this software.
    
    Permission is granted to anyone to use this software for any purpose,
    including commercial applications, and to alter it and redistribute it
    freely, subject to the following restrictions:
    
    1. The origin of this software must not be misrepresented; you must not
       claim that you wrote the original software. If you use this software
       in a product, an acknowledgment in the product documentation would be
       appreciated but is not required.
    2. Altered source versions must be plainly marked as such, and must not be
       misrepresented as being the original software.
    3. This notice may not be removed or altered from any source distribution.
*/

import std.socket, std.stdio, std.string, std.ctype;
import splat;


class IrcClientSocket: AsyncTcpSocket
{
    char[] nick;
    SocketQueue queue;
    
    
    char[] fulladdress() // getter
    {
        return nick ~ "!user@foo.bar";
    }
    
    
    bool allowed() // getter
    {
        return 0 != nick.length;
    }
    
    
    void sendLine(char[] s)
    {
        queue.send(s ~ "\r\n");
    }
    
    
    void onLine(char[] line)
    {
        int i;
        
        char[] cmd;
        i = std.string.find(line, ' ');
        if(-1 == i)
        {
            cmd = line;
            line = null;
        }
        else
        {
            cmd = line[0 .. i];
            line = line[i + 1 .. line.length];
        }
        cmd = std.string.toupper(cmd);
        
        // Handle commands...
        if(!allowed)
        {
            switch(cmd)
            {
                case "NICK":
                    for(i = 0; i != line.length; i++)
                    {
                        if(!std.ctype.isalnum(line[i]) && '_' != line[i]
                            && '[' != line[i] && ']' != line[i] && '-' != line[i])
                            break;
                    }
                    line = line[0 .. i];
                    if(!line.length || std.ctype.isdigit(line[0]))
                    {
                        sendLine(":foo.bar 432  :Bad nickname!");
                    }
                    else
                    {
                        foreach(client; clients)
                        {
                            if(!std.string.icmp(client.nick, line))
                            {
                                sendLine(":foo.bar 433  :That nickname is in use!");
                                goto nick_done;
                            }
                        }
                        
                        nick = line.dup;
                        
                        sendLine(":foo.bar 001 " ~ nick ~ " :Welcome to SPLAT!");
                        sendLine(":foo.bar 002 " ~ nick ~ " :Your host is foo.bar");
                        sendLine(":foo.bar 003 " ~ nick ~ " :This server was created Fri Dec 8 2006 at 14:00:00 GMT");
                        sendLine(":foo.bar 422 " ~ nick ~ " :No MOTD");
                        
                        clients[this] = this;
                        
                        broadcast(":" ~ fulladdress ~ " JOIN #splat");
                        sendNamesList();
                    }
                    nick_done:
                    break;
                
                case "QUIT":
                    clients.remove(this);
                    close();
                    break;
                
                default: ;
            }
        }
        else // allowed
        {
            switch(cmd)
            {
                case "QUIT":
                    clients.remove(this);
                    close();
                    //broadcast(":" ~ fulladdress ~ " QUIT " ~ line);
                    if(!line.length || ":" == line)
                    {
                        broadcast(":" ~ fulladdress ~ " QUIT");
                    }
                    else
                    {
                        if(':' == line[0])
                            line = line[1 .. line.length];
                        broadcast(":" ~ fulladdress ~ " QUIT :Quit: " ~ line);
                    }
                    break;
                
                case "PRIVMSG":
                    i = std.string.find(line, ' ');
                    if(-1 != i)
                    {
                        if(!std.string.icmp(line[0 .. i], "#splat"))
                        {
                            line = line[i + 1 .. line.length];
                            if(line.length)
                            {
                                broadcastButOne(":" ~ fulladdress ~ " PRIVMSG #splat " ~ line, this);
                            }
                        }
                        else
                        {
                            cantdothat();
                        }
                    }
                    break;
                
                case "NOTICE":
                    cantdothat();
                    break;
                
                case "NAMES":
                    i = std.string.find(line, ' ');
                    if(-1 != i)
                    {
                        if(!std.string.icmp(line[0 .. i], "#splat"))
                        {
                            sendNamesList();
                        }
                    }
                    break;
                
                case "PING":
                    sendLine(":foo.bar PONG foo.bar " ~ line);
                    break;
                
                default: ;
            }
        }
    }
    
    
    void sendNamesList()
    {
        char[] s;
        s = ":foo.bar 353 " ~ nick ~ " = #splat :";
        foreach(client; clients)
        {
            if(client.allowed)
            {
                s ~= client.nick;
                s ~= " ";
            }
        }
        sendLine(s);
        sendLine(":foo.bar 366 " ~ nick ~ " #splat :End of /NAMES list.");
    }
    
    
    void cantdothat()
    {
        //sendLine(":the.server PRIVMSG " ~ nick ~ " :You can't do that!");
    }
    
    
    void gotReadEvent()
    {
        byte[] peek;
        find_line:
        peek = cast(byte[])queue.peek();
        foreach(idx, b; peek)
        {
            if('\r' == b || '\n' == b)
            {
                if(!idx)
                {
                    queue.receive(1); // Remove from queue.
                    goto find_line;
                }
                queue.receive(idx + 1); // Remove from queue.
                onLine(cast(char[])peek[0 .. idx]);
                goto find_line;
            }
        }
    }
    
    
    void netEvent(Socket sock, EventType type, int err)
    {
        if(err)
        {
            clients.remove(this);
            close();
            if(allowed)
                broadcast(":" ~ fulladdress ~ " QUIT :Connection error");
            return;
        }
        
        switch(type)
        {
            case EventType.CLOSE:
                clients.remove(this);
                close();
                if(allowed)
                    broadcast(":" ~ fulladdress ~ " QUIT :Connection closed");
                break;
            
            case EventType.READ:
                queue.readEvent();
                if(queue.receiveBytes > 1024 * 4)
                {
                    clients.remove(this);
                    close();
                    queue.reset();
                    if(allowed)
                        broadcast(":" ~ fulladdress ~ " QUIT :Excess flood");
                }
                else
                {
                    gotReadEvent();
                }
                break;
            
            case EventType.WRITE:
                if(queue.sendBytes > 1024 * 8)
                {
                    clients.remove(this);
                    close();
                    queue.reset();
                    if(allowed)
                        broadcast(":" ~ fulladdress ~ " QUIT :Excess send-queue");
                }
                else
                {
                    queue.writeEvent();
                }
                break;
            
            default: ;
        }
    }
}


class IrcListenSocket: AsyncTcpSocket
{
    override IrcClientSocket accepting()
    {
        return new IrcClientSocket();
    }
    
    
    void netEvent(Socket sock, EventType type, int err)
    {
        if(!err)
        {
            IrcClientSocket nsock;
            nsock = cast(IrcClientSocket)sock.accept();
            writefln("Connection accepted from %s", nsock.remoteAddress);
            nsock.queue = new SocketQueue(nsock);
            nsock.event(EventType.READ | EventType.WRITE | EventType.CLOSE, &nsock.netEvent);
        }
    }
}


IrcClientSocket[IrcClientSocket] clients;


void broadcast(char[] s)
{
    foreach(client; clients)
    {
        client.sendLine(s);
    }
}


void broadcastButOne(char[] s, IrcClientSocket except)
{
    foreach(client; clients)
    {
        if(client !is except)
            client.sendLine(s);
    }
}


void main()
{
    bool done = false;
    scope lsock = new IrcListenSocket;
    scope lsockaddr = new InternetAddress(InternetAddress.ADDR_ANY, 1667); // Not standard IRC port.. not standard IRC server.
    lsock.bind(lsockaddr);
    lsock.listen(10);
    lsock.event(EventType.ACCEPT, &lsock.netEvent);
    writefln("Server ready");
    do
    {
        try
        {
            splat.run();
            done = true; // run returned upon request.
        }
        catch(Object o)
        {
            writefln("Error: %s", o);
        }
    }
    while(!done);
}